@echo off
chcp 65001 >nul
title AIFENG DCS - Install Desktop App
set "APP_URL=https://app.aifengdcs.com/desk/"
set "APP_NAME=AIFENG DCS"

set "CHROME="
if exist "%ProgramFiles%\Google\Chrome\Application\chrome.exe" set "CHROME=%ProgramFiles%\Google\Chrome\Application\chrome.exe"
if exist "%ProgramFiles(x86)%\Google\Chrome\Application\chrome.exe" set "CHROME=%ProgramFiles(x86)%\Google\Chrome\Application\chrome.exe"
if exist "%LocalAppData%\Google\Chrome\Application\chrome.exe" set "CHROME=%LocalAppData%\Google\Chrome\Application\chrome.exe"

if not defined CHROME (
  echo [ERROR] Chrome not found. Please install Google Chrome first.
  echo [ERROR] Wei zhao dao Chrome, qing xian an zhuang Google Chrome.
  pause
  exit /b 1
)

echo Found Chrome: %CHROME%
echo Creating desktop shortcut: %APP_NAME%  --app=%APP_URL%

powershell -NoProfile -ExecutionPolicy Bypass -Command ^
  "$ws = New-Object -ComObject WScript.Shell;" ^
  "$desktop = $ws.SpecialFolders('Desktop');" ^
  "$lnk = $ws.CreateShortcut((Join-Path $desktop '%APP_NAME%.lnk'));" ^
  "$lnk.TargetPath = '%CHROME%';" ^
  "$lnk.Arguments = '--app=%APP_URL%';" ^
  "$lnk.WorkingDirectory = '%ProgramFiles%';" ^
  "$lnk.IconLocation = '%CHROME%,0';" ^
  "$lnk.Description = 'AIFENG DCS Desktop (Chrome app mode)';" ^
  "$lnk.Save()"

if errorlevel 1 (
  echo [ERROR] Shortcut creation failed.
  pause
  exit /b 1
)

echo.
echo [OK] Desktop shortcut created: %APP_NAME%
echo [OK] Zhuo mian kuai jie fang shi yi chuang jian, shuang ji ji ke da kai AIFENG DCS zhuo mian ban.
echo URL: %APP_URL%
pause